home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Software Vault: The Diamond Collection
/
The Diamond Collection (Software Vault)(Digital Impact).ISO
/
cdr37
/
pfed_092.zip
/
BOOMSCAN.BAT
< prev
next >
Wrap
DOS Batch File
|
1995-04-25
|
5KB
|
181 lines
@ECHO OFF
REM ---------------------------------------------
REM *** VIRUS SCANNER HANDLER - DO NOT DELETE ***
REM ---------------------------------------------
IF "%1"=="" GOTO ENDE
IF "%3"=="" GOTO ENDE
IF EXIST SCANFAIL.%4 DEL SCANFAIL.%4 >NUL
IF EXIST SCANLOG.%4 DEL SCANLOG.%4 >NUL
IF %2 == 1 GOTO OLDSCAN
IF %2 == 2 GOTO NEWSCAN
IF %2 == 3 GOTO TBSCAN
IF %2 == 4 GOTO DRSOLOMON
IF %2 == 5 GOTO FPROT
IF %2 == 6 GOTO AVSCAN
GOTO NOSCANNER
REM *** MCAFEE VIRUS SCAN (SCAN)*****************************************
:OLDSCAN
%1 /A /NOMEM /NOBREAK /NOPAUSE /NOEXPIRE /REPORT SCANLOG.%4 %3
IF ERRORLEVEL 4 GOTO CTRLBREAK
IF ERRORLEVEL 3 GOTO UNCERTIFIED
IF ERRORLEVEL 2 GOTO PROGERROR
IF ERRORLEVEL 1 GOTO VIRUSFOUND
GOTO NOVIRUS
REM *** MCAFEE NEW VIRUS SCAN (SCAN)*************************************
:NEWSCAN
REM %1=Virus Scanner, %3=Path to Scan, %4=Node, %5=Optional Switches
%1 /ALL /NOMEM /NOBREAK /REPORT SCANLOG.%4 %3
IF ERRORLEVEL 255 GOTO PROGERROR
IF ERRORLEVEL 18 GOTO UNCERTIFIED
IF ERRORLEVEL 17 GOTO NOFILES
IF ERRORLEVEL 16 GOTO IOERROR
IF ERRORLEVEL 15 GOTO SELFCHECK
IF ERRORLEVEL 14 GOTO OUTOFDATE
IF ERRORLEVEL 13 GOTO VIRUSFOUND
IF ERRORLEVEL 12 GOTO PROGERROR
IF ERRORLEVEL 11 GOTO PROGERROR
IF ERRORLEVEL 10 GOTO VIRUSFOUND
IF ERRORLEVEL 9 GOTO CMDLINERROR
IF ERRORLEVEL 8 GOTO FILEMISSING
IF ERRORLEVEL 7 GOTO FILEMISSING
IF ERRORLEVEL 6 GOTO PROGERROR
IF ERRORLEVEL 5 GOTO NOMEMORY
IF ERRORLEVEL 4 GOTO PROGERROR
IF ERRORLEVEL 3 GOTO PROGERROR
IF ERRORLEVEL 2 GOTO FILEMISSING
IF ERRORLEVEL 1 GOTO IOERROR
GOTO NOVIRUS
REM *** THUNDER-BYTE (TBSCAN.EXE)****************************************
:TBSCAN
REM %1=Virus Scanner, %3=Path to Scan, %4=Node, %5=Optional Switches
%1 %5 NM NB BA LO OL %3 >NUL
IF ERRORLEVEL 255 GOTO PROGERROR
IF ERRORLEVEL 5 GOTO VIRUSFOUND
IF ERRORLEVEL 4 GOTO VIRUSFOUND
IF ERRORLEVEL 3 GOTO NOVIRUS
IF ERRORLEVEL 2 GOTO PROGERROR
IF ERRORLEVEL 1 GOTO NOFILES
GOTO NOVIRUS
REM *** DR SOLOMON'S (FINDVIRU.EXE)**************************************
:DRSOLOMON
REM %1=Virus Scanner, %3=Path to Scan, %4=Node, %5=Optional Switches
%1 /NOBOOT /NOPART /DOALLFILES /REPORT=SCANLOG.%4 %3
IF ERRORLEVEL 255 GOTO CTRLBREAK
IF ERRORLEVEL 3 GOTO PROGERROR
IF ERRORLEVEL 2 GOTO VIRUSFOUND
IF ERRORLEVEL 1 GOTO PROGERROR
GOTO NOVIRUS
REM *** F-PROT (F-PROT.EXE)**********************************************
:FPROT
REM %1=Virus Scanner, %3=Path to Scan, %5=Optional Switches (/A /ANALYSE)
%1 %5 /NOMEM /NOBOOT /NOBREAK /OLD /REPORT=SCANLOG.%4 %3
IF ERRORLEVEL 255 GOTO PROGERROR
IF ERRORLEVEL 8 GOTO POSSIBLEVIRUS
IF ERRORLEVEL 7 GOTO NOMEMORY
IF ERRORLEVEL 6 GOTO VIRUSFOUND
IF ERRORLEVEL 5 GOTO CTRLBREAK
IF ERRORLEVEL 4 GOTO VIRUSFOUND
IF ERRORLEVEL 3 GOTO VIRUSFOUND
IF ERRORLEVEL 2 GOTO SELFCHECK
IF ERRORLEVEL 1 GOTO PROGERROR
GOTO NOVIRUS
REM *** AVSCAN (AVSCAN.EXE)**********************************************
:AVSCAN
%1 /NM /NB /NESC /R /Q %3 /LSCANLOG.%4
IF ERRORLEVEL 255 GOTO OUTOFDATE
IF ERRORLEVEL 100 GOTO VIRUSFOUND
IF ERRORLEVEL 10 GOTO IOERROR
IF ERRORLEVEL 8 GOTO NOFILES
IF ERRORLEVEL 7 GOTO VIRUSFOUND
IF ERRORLEVEL 6 GOTO SELFCHECK
IF ERRORLEVEL 5 GOTO CTRLBREAK
IF ERRORLEVEL 4 GOTO IOERROR
IF ERRORLEVEL 3 GOTO NOMEMORY
IF ERRORLEVEL 2 GOTO WRONGDOS
IF ERRORLEVEL 1 GOTO CMDLINERROR
GOTO NOVIRUS
REM *** SCANNER ERRORS **************************************************
:NOSCANNER
ECHO VIRUS SCANNER NOT FOUND >SCANFAIL.%4
ECHO 3 >>SCANFAIL.%4
GOTO ENDE
:CTRLBREAK
ECHO SCANNER INTERRUPTED BY USER >SCANFAIL.%4
ECHO 3 >>SCANFAIL.%4
GOTO ENDE
:PROGERROR
ECHO VIRUS PROGRAM ERROR!!! >SCANFAIL.%4
ECHO 3 >>SCANFAIL.%4
GOTO ENDE
:WRONGDOS
ECHO INCORRECT DOS VERSION! >SCANFAIL.%4
ECHO 3 >>SCANFAIL.%4
GOTO ENDE
:CMDLINERROR
ECHO COMMAND LINE ERROR! >SCANFAIL.%4
ECHO 3 >>SCANFAIL.%4
GOTO ENDE
:IOERROR
ECHO I/O ERROR! >SCANFAIL.%4
ECHO 3 >>SCANFAIL.%4
GOTO ENDE
:NOMEMORY
ECHO INSUFFICIENT MEMORY! >SCANFAIL.%4
ECHO 3 >>SCANFAIL.%4
GOTO ENDE
:FILEMISSING
ECHO REQUIRED FILE MISSING OR BAD! >SCANFAIL.%4
ECHO 3 >>SCANFAIL.%4
GOTO ENDE
:UNCERTIFIED
ECHO FAILED CERTIFICATION! >SCANFAIL.%4
ECHO 3 >>SCANFAIL.%4
GOTO ENDE
:OUTOFDATE
ECHO SCANNER OUTDATED! >SCANFAIL.%4
ECHO 3 >>SCANFAIL.%4
GOTO ENDE
:SELFCHECK
ECHO SCANNER SELF-CHECK FAILED! >SCANFAIL.%4
ECHO 2 >>SCANFAIL.%4
GOTO ENDE
:POSSIBLEVIRUS
ECHO POSSIBLE VIRUS! >SCANFAIL.%4
ECHO 2 >>SCANFAIL.%4
GOTO ENDE
:VIRUSFOUND
ECHO VIRUS INFECTED!!! >SCANFAIL.%4
ECHO 1 >>SCANFAIL.%4
GOTO ENDE
:NOFILES
ECHO No Files Found >SCANFAIL.%4
ECHO 0 >>SCANFAIL.%4
GOTO ENDE
:NOVIRUS
ECHO No Viruses Found >SCANFAIL.%4
ECHO 0 >>SCANFAIL.%4
GOTO ENDE
:ENDE